Projects/Maintenance

Some topical projects initiated by the WMSE team to create basic data. See what's been done and how you can help out. Conferences • This Month in GLAM • GLAM events • Support items • OpenRefine • Maintenance

Here we have collected some queries to help find areas where the data should be improved.

🖊️ Help out by fixing some issues.

Duplicates based on Wikidata ID

🔴 Should give 0 results.

If two items have an identical same as on Wikidata (P1) they are most probably duplicates. Special:MergeItems can be used to merge them.

#Items with non-unique Wikidata ID

PREFIX wb: <https://metabase.wikibase.cloud/entity/>
PREFIX wbt: <https://metabase.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item1 ?item1Label ?item2 ?item2Label ?value WHERE {
  ?item1 wbt:P1 ?value.
  ?item2 wbt:P1 ?value.
  FILTER((?item1 != ?item2) && ((STR(?item1)) < (STR(?item2))))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,sv". }
}

Try it!

Index terms without Wikidata ID

🔴 Should give 0 results.

Anything that is instance of (P5) = index term (Q12) needs to have a same as on Wikidata (P1).

#Index terms without Wikidata ID

PREFIX wb: <https://metabase.wikibase.cloud/entity/>
PREFIX wbt: <https://metabase.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel
WHERE {?item wbt:P5 wb:Q12. MINUS {?item wbt:P1 []}
SERVICE wikibase:label { bd:serviceParam wikibase:language "sv,en". }
}

Try it!

Events where we don't know if they were online or physical

🔴 Should give 0 results.

Every event should have a statement instance of (P5) with one of these three values: online event (Q81), in-person event (Q80), hybrid event (Q79) (of course, in addition to what type of event it is, like edit-a-thon (Q41) etc).

Example: Metadata edit-a-thon at the Swedish Air Force Museum (Q82).

#Events (excluding campaigns, photo contests) without indication whether they're online, in-person or hybrid

PREFIX wb: <https://metabase.wikibase.cloud/entity/>
PREFIX wbt: <https://metabase.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel
WHERE
{?item wbt:P5/wbt:P4* wb:Q40 . # is an event
MINUS {?item wbt:P5 wb:Q81} # is not an online event
MINUS {?item wbt:P5 wb:Q80} # is not an in-person event
MINUS {?item wbt:P5 wb:Q79} # is not a hybrid event
MINUS {?item wbt:P5 wb:Q22217} # is not a campaign
MINUS {?item wbt:P5 wb:Q142} # is not a photo contest
MINUS {?item wbt:P5 wb:Q24323} # is not a event sequence
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,sv,it,pt". }}

Try it!

Temporary Free Text fields

🟡 May give some results, the point of the field is to leave a note for yourself or others to create an item later.

We use temporary free text field (P38) as an equivalent of Wikidata's author name string, but not limited to author statements. The qualifier replaced by property (P41) specifies what sort sort of information is stored in the statement.

#All Temporary Free Text Fields

PREFIX wb: <https://metabase.wikibase.cloud/entity/>
PREFIX wbt: <https://metabase.wikibase.cloud/prop/direct/>
PREFIX wbp: <https://metabase.wikibase.cloud/prop/>
PREFIX wbpq: <https://metabase.wikibase.cloud/prop/qualifier/>
SELECT DISTINCT ?item ?itemLabel ?val ?qual ?qualLabel
WHERE
{?item wbt:P38 ?val. OPTIONAL {?item wbp:P38 ?statement. ?statement wbpq:P41 ?qual .}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,sv". }
}

Try it!

Organizations without a Wikidata ID

🟡 May give some results, for organizations that are not notable for Wikidata.

Should be addressed by adding same as on Wikidata (P1). In some cases you will need to create the Wikidata item first, if the organization is notable enough for Wikidata. Many of them probably are.

#Organizations without Wikidata ID

PREFIX wb: <https://metabase.wikibase.cloud/entity/>
PREFIX wbt: <https://metabase.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel
WHERE
{
?item wbt:P5 wb:Q13 .
MINUS {?item wbt:P1 [].}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,sv". }
}

Try it!