Projects/Conferences

Some topical projects initiated by the WMSE team to create basic data. See what's been done and how you can help out. Conferences • This Month in GLAM • GLAM events • Support items • OpenRefine • Maintenance

We would like to collect data about conferences and other large events organized by the Wikimedia movement. Here you can find some relevant queries and examples.

Conferences organized by the Wikimedia movement

Since Metabase only records basic information about organizations (see Wikimedia Deutschland (Q21767)), we use federation with Wikidata to find out whether a conference organizer is part of the Wikimedia movement. Following the same as on Wikidata (P1), we check in Wikidata whether the organizer has part of = Wikimedia movement.

🚧 Only a small part of the conferences have items in Metabase.

🖊️ Help out by adding a conference. See examples: WikidataCon 2017 (Q23216), GLAM Wiki 2023 (Q22660).

Wikidata query – all Wikidata items that are a Wikimedia conference, and whether or not they exist in Metabase.

#Conferences whose organizer is (via Wikidata lookup) part of the Wikimedia movement

PREFIX wb: <https://metabase.wikibase.cloud/entity/>
PREFIX wbt: <https://metabase.wikibase.cloud/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT DISTINCT ?item ?itemLabel ?locationLabel (GROUP_CONCAT(DISTINCT ?orgLabel; SEPARATOR = ", ") AS ?organizers) ?coord WHERE {
  ?item wbt:P5 wb:Q42;
    wbt:P14 ?org;
    wbt:P27 ?location.
  ?location wbt:P1 ?locationQ.
  ?org wbt:P5 wb:Q13;
    wbt:P1 ?wikidataQ.
  BIND(URI(CONCAT("http://www.wikidata.org/entity/", ?wikidataQ)) AS ?wikidata_iri)
  BIND(URI(CONCAT("http://www.wikidata.org/entity/", ?locationQ)) AS ?location_wikidata_iri)
  SERVICE <https://query.wikidata.org/sparql> {
    ?wikidata_iri wdt:P361 wd:Q3568028.
    ?location_wikidata_iri wdt:P625 ?coord.
  }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en,sv,es".
    ?item rdfs:label ?itemLabel.
    ?org rdfs:label ?orgLabel.
    ?location rdfs:label ?locationLabel.
  }
}
GROUP BY ?item ?itemLabel ?locationLabel ?coord

Try it!

Wikimania

✅ Items for all Wikimania (Q34328) up-to-date (to and including Wikimania 2024 (Q24144)) have been created.

🖊️ Help out by adding a Wikimania session you watched or held! Here's an example: Wikispeech - making Wikipedia accessible through speech technology (Q25172)

All Wikimanias

# All Wikimania conferences

PREFIX wb: <https://metabase.wikibase.cloud/entity/>
PREFIX wbt: <https://metabase.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?placeLabel ?start ?end ?in_wikidata
WHERE
{
?item wbt:P17 wb:Q34328.
?item wbt:P1 ?wikidataQ
BIND(URI(concat("http://www.wikidata.org/entity/", ?wikidataQ)) AS ?in_wikidata)
OPTIONAL {?item wbt:P27 ?place}
OPTIONAL {
?item wbt:P6 ?start.
?item wbt:P7 ?end.
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,sv". }
}
ORDER BY ?itemLabel

Try it!

All sessions that were part of a Wikimania

# All sessions that are part of Wikimania
PREFIX wb: <https://metabase.wikibase.cloud/entity/>
PREFIX wbt: <https://metabase.wikibase.cloud/prop/direct/>
SELECT ?conferenceLabel ?conferencepart ?conferencepartLabel ?when
WHERE
{
?conference wbt:P17 wb:Q34328.
?conference wbt:P35 ?conferencepart.
OPTIONAL {?conferencepart wbt:P23 ?when}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,sv". }
}

Try it!