Modelling/Events and activities/Conferences

 Modelling

Documents — Index terms — Humans — Events and activities (Conferences) — Projects — Content uploads (Resource types)

Modeling a conference

GLAM Wiki 2023 (Q22660) is used as an example here.

Session structure

• A conference (Q42) normally consists of several session (Q22726).
  • These are linked using has part(s) (P35) / part of (P17).
• session (Q22726) can be either of hybrid event (Q79), in-person event (Q80), online event (Q81). Thus, every session has two instance of (P5).
• session (Q22726) contains one or more of specific activities. For example, a session can contain three separate presentations, by different speakers, on the same topic. What brings them together is that they are grouped as one session in the program.
  • This is modeled using has part(s) of the class (P66) and the qualifier quantity (P62).
  • Example: Wikidata for cultural heritage (Q22701), which contains 3 presentations. Compare the description in the conference program.
• session (Q22726) can have one or more speaker (P33) (people who present) or manager / leader (P32) (people who facilitate a practical activity, like a workshop).

SPARQL

All conferences

PREFIX wb: <https://metabase.wikibase.cloud/entity/>
PREFIX wbt: <https://metabase.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?where ?whereLabel ?when ?start ?end
WHERE
{
?item wbt:P5/wbt:P4* wb:Q42 .
OPTIONAL {?item wbt:P23 ?when}
OPTIONAL {?item wbt:P27 ?where}
OPTIONAl {?item wbt:P6 ?start}
OPTIONAL {?item wbt:P7 ?end}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,sv". }
}

Try it!

Everything that is part of GLAM Wiki 2023, including the dates, people involved, and main subjects

PREFIX wb: <https://metabase.wikibase.cloud/entity/>
PREFIX wbt: <https://metabase.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel (GROUP_CONCAT(DISTINCT ?typeLabel; SEPARATOR = ", ") AS ?types) ?when (GROUP_CONCAT(DISTINCT ?personLabel; SEPARATOR = ", ") AS ?persons) (GROUP_CONCAT(DISTINCT ?mainsubjectLabel; SEPARATOR = ", ") AS ?topics)
WHERE
{
?item wbt:P17* wb:Q22660.
?item wbt:P5 ?type.
OPTIONAL {?item wbt:P23 ?when}
OPTIONAL {?item wbt:P32 ?person} # leader, eg in a workshop
OPTIONAL {?item wbt:P33 ?person} # speaker, eg in a presentation
OPTIONAL {?item wbt:P19 ?person} # author, eg of a video
OPTIONAL {?item wbt:P15 ?mainsubject}
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en,sv,es".
    ?item rdfs:label ?itemLabel.
    ?person rdfs:label ?personLabel.
    ?mainsubject rdfs:label ?mainsubjectLabel.
    ?type rdfs:label ?typeLabel.
  }
}
GROUP BY ?item ?itemLabel ?types ?when
ORDER BY ?itemLabel

Try it!